Julia 復(fù)數(shù)和分數(shù)

Julia 提供復(fù)數(shù)和分數(shù)類型，并對其支持所有的標準數(shù)學(xué)運算 。對不同的數(shù)據(jù)類型進行混合運算時，無論是基礎(chǔ)的還是復(fù)合的，都會自動使用類型轉(zhuǎn)換和類型提升。

復(fù)數(shù)

全局變量 im 即復(fù)數(shù) i ，表示 -1 的正平方根。因為 i 經(jīng)常作為索引變量，所以不使用它來代表復(fù)數(shù)了。Julia 允許數(shù)值文本作為代數(shù)系數(shù) ，也適用于復(fù)數(shù)：

julia> 1 + 2im
1 + 2im

可以對復(fù)數(shù)做標準算術(shù)運算：

julia> (1 + 2im)*(2 - 3im)
8 + 1im

julia> (1 + 2im)/(1 - 2im)
-0.6 + 0.8im

julia> (1 + 2im) + (1 - 2im)
2 + 0im

julia> (-3 + 2im) - (5 - 1im)
-8 + 3im

julia> (-1 + 2im)^2
-3 - 4im

julia> (-1 + 2im)^2.5
2.7296244647840084 - 6.960664459571898im

julia> (-1 + 2im)^(1 + 1im)
-0.27910381075826657 + 0.08708053414102428im

julia> 3(2 - 5im)
6 - 15im

julia> 3(2 - 5im)^2
-63 - 60im

julia> 3(2 - 5im)^-1.0
0.20689655172413796 + 0.5172413793103449im

類型提升機制保證了不同類型的運算對象能夠在一起運算：

julia> 2(1 - 1im)
2 - 2im

julia> (2 + 3im) - 1
1 + 3im

julia> (1 + 2im) + 0.5
1.5 + 2.0im

julia> (2 + 3im) - 0.5im
2.0 + 2.5im

julia> 0.75(1 + 2im)
0.75 + 1.5im

julia> (2 + 3im) / 2
1.0 + 1.5im

julia> (1 - 3im) / (2 + 2im)
-0.5 - 1.0im

julia> 2im^2
-2 + 0im

julia> 1 + 3/4im
1.0 - 0.75im

注意： 3/4im == 3/(4*im) == -(3/4*im) ，因為文本系數(shù)比除法優(yōu)先。

處理復(fù)數(shù)的標準函數(shù)：

julia> real(1 + 2im)
1

julia> imag(1 + 2im)
2

julia> conj(1 + 2im)
1 - 2im

julia> abs(1 + 2im)
2.23606797749979

julia> abs2(1 + 2im)
5

julia> angle(1 + 2im)
1.1071487177940904

通常， 復(fù)數(shù)的絕對值( abs )是它到零的距離。 函數(shù) abs2 返回絕對值的平方， 特別地用在復(fù)數(shù)上來避免開根。angle 函數(shù)返回弧度制的相位(即 argument 或 arg )。 所有的基本函數(shù)也可以應(yīng)用在復(fù)數(shù)上：

julia> sqrt(1im)
0.7071067811865476 + 0.7071067811865475im

julia> sqrt(1 + 2im)
1.272019649514069 + 0.7861513777574233im

julia> cos(1 + 2im)
2.0327230070196656 - 3.0518977991518im

julia> exp(1 + 2im)
-1.1312043837568135 + 2.4717266720048188im

julia> sinh(1 + 2im)
-0.4890562590412937 + 1.4031192506220405im

作用在實數(shù)上的數(shù)學(xué)函數(shù)，返回值一般為實數(shù)；作用在復(fù)數(shù)上的，返回值為復(fù)數(shù)。例如， sqrt 對 -1 和 -1 + 0im 的結(jié)果不同，即使 -1 == -1 + 0im ：

julia> sqrt(-1)
ERROR: DomainError
sqrt will only return a complex result if called with a complex argument.
try sqrt(complex(x))
 in sqrt at math.jl:131

julia> sqrt(-1 + 0im)
0.0 + 1.0im

代數(shù)系數(shù)不能用于使用變量構(gòu)造復(fù)數(shù)。乘法必須顯式的寫出來：

julia> a = 1; b = 2; a + b*im
1 + 2im

但是， 不 推薦使用上面的方法。推薦使用 complex 函數(shù)構(gòu)造復(fù)數(shù)：

julia> complex(a,b)
1 + 2im

這種構(gòu)造方式避免了乘法和加法操作。

Inf 和 NaN 也可以參與構(gòu)造復(fù)數(shù) (參考特殊的浮點數(shù)部分)：

julia> 1 + Inf*im
1.0 + Inf*im

julia> 1 + NaN*im
1.0 + NaN*im

分數(shù) Julia 有分數(shù)類型。使用 // 運算符構(gòu)造分數(shù)：

julia> 2//3
2//3

如果分子、分母有公約數(shù)，將自動約簡至最簡分數(shù)，且分母為非負數(shù)：

julia> 6//9
2//3

julia> -4//8
-1//2

julia> 5//-15
-1//3

julia> -4//-12
1//3

約簡后的分數(shù)都是唯一的，可以通過分別比較分子、分母來確定兩個分數(shù)是否相等。使用 num 和 den 函數(shù)來取得約簡后的分子和分母：

julia> num(2//3)
2

julia> den(2//3)
3

其實并不需要比較分數(shù)和分母，我們已經(jīng)為分數(shù)定義了標準算術(shù)和比較運算：

julia> 2//3 == 6//9
true

julia> 2//3 == 9//27
false

julia> 3//7 < 1//2
true

julia> 3//4 > 2//3
true

julia> 2//4 + 1//6
2//3

julia> 5//12 - 1//4
1//6

julia> 5//8 * 3//12
5//32

julia> 6//5 / 10//7
21//25

分數(shù)可以簡單地轉(zhuǎn)換為浮點數(shù)：

julia> float(3//4)
0.75

分數(shù)到浮點數(shù)的轉(zhuǎn)換遵循，對任意整數(shù) a 和 b ，除 a == 0 及 b == 0 之外，有：

julia> isequal(float(a//b), a/b)
true

可以構(gòu)造結(jié)果為 Inf 的分數(shù)：

julia> 5//0
1//0

julia> -3//0
-1//0

julia> typeof(ans)
Rational{Int64} (constructor with 1 method)

但不能構(gòu)造結(jié)果為 NaN 的分數(shù)：

julia> 0//0
ERROR: invalid rational: 0//0
 in Rational at rational.jl:6
 in // at rational.jl:15

類型提升系統(tǒng)使得分數(shù)類型與其它數(shù)值類型交互非常簡單：

julia> 3//5 + 1
8//5

julia> 3//5 - 0.5
0.09999999999999998

julia> 2//7 * (1 + 2im)
2//7 + 4//7*im

julia> 2//7 * (1.5 + 2im)
0.42857142857142855 + 0.5714285714285714im

julia> 3//2 / (1 + 2im)
3//10 - 3//5*im

julia> 1//2 + 2im
1//2 + 2//1*im

julia> 1 + 2//3im
1//1 - 2//3*im

julia> 0.5 == 1//2
true

julia> 0.33 == 1//3
false

julia> 0.33 < 1//3
true

julia> 1//3 - 0.33
0.0033333333333332993