Spring Cloud 使用自定義Stub Runner

如果決定使用自定義存根生成，則還需要使用自定義方式與其他存根提供程序一起運(yùn)行存根。

假設(shè)您使用Moco來(lái)構(gòu)建存根，并且已經(jīng)編寫(xiě)了存根生成器并將存根放置在JAR文件中。

為了使Stub Runner知道如何運(yùn)行存根，您必須定義一個(gè)自定義HTTP Stub服務(wù)器實(shí)現(xiàn)，該實(shí)現(xiàn)可能類(lèi)似于以下示例：

package org.springframework.cloud.contract.stubrunner.provider.moco

import com.github.dreamhead.moco.bootstrap.arg.HttpArgs
import com.github.dreamhead.moco.runner.JsonRunner
import com.github.dreamhead.moco.runner.RunnerSetting
import groovy.util.logging.Commons

import org.springframework.cloud.contract.stubrunner.HttpServerStub
import org.springframework.util.SocketUtils

@Commons
class MocoHttpServerStub implements HttpServerStub {

	private boolean started
	private JsonRunner runner
	private int port

	@Override
	int port() {
		if (!isRunning()) {
			return -1
		}
		return port
	}

	@Override
	boolean isRunning() {
		return started
	}

	@Override
	HttpServerStub start() {
		return start(SocketUtils.findAvailableTcpPort())
	}

	@Override
	HttpServerStub start(int port) {
		this.port = port
		return this
	}

	@Override
	HttpServerStub stop() {
		if (!isRunning()) {
			return this
		}
		this.runner.stop()
		return this
	}

	@Override
	HttpServerStub registerMappings(Collection<File> stubFiles) {
		List<RunnerSetting> settings = stubFiles.findAll { it.name.endsWith("json") }
			.collect {
			log.info("Trying to parse [${it.name}]")
			try {
				return RunnerSetting.aRunnerSetting().withStream(it.newInputStream()).
					build()
			}
			catch (Exception e) {
				log.warn("Exception occurred while trying to parse file [${it.name}]", e)
				return null
			}
		}.findAll { it }
		this.runner = JsonRunner.newJsonRunnerWithSetting(settings,
			HttpArgs.httpArgs().withPort(this.port).build())
		this.runner.run()
		this.started = true
		return this
	}

	@Override
	String registeredMappings() {
		return ""
	}

	@Override
	boolean isAccepted(File file) {
		return file.name.endsWith(".json")
	}
}

然后，可以將其注冊(cè)到spring.factories文件中，如以下示例所示：

org.springframework.cloud.contract.stubrunner.HttpServerStub=\
org.springframework.cloud.contract.stubrunner.provider.moco.MocoHttpServerStub

現(xiàn)在，您可以使用Moco運(yùn)行存根。

如果不提供任何實(shí)現(xiàn)，則使用默認(rèn)（WireMock）實(shí)現(xiàn)。如果提供多個(gè)??，則使用列表中的第一個(gè)。