Julia
2018-02-24 15:18 更新
X分鐘速成Y
其中 Y=Julia
源代碼下載：?learn-julia-zh.jl
# 單行注釋只需要一個(gè)井號(hào)
#= 多行注釋
只需要以 '#=' 開(kāi)始 '=#' 結(jié)束
還可以嵌套.
=#
####################################################
## 1\. 原始類(lèi)型與操作符
####################################################
# Julia 中一切皆是表達(dá)式。
# 這是一些基本數(shù)字類(lèi)型.
3 # => 3 (Int64)
3.2 # => 3.2 (Float64)
2 + 1im # => 2 + 1im (Complex{Int64})
2//3 # => 2//3 (Rational{Int64})
# 支持所有的普通中綴操作符。
1 + 1 # => 2
8 - 1 # => 7
10 * 2 # => 20
35 / 5 # => 7.0
5 / 2 # => 2.5 # 用 Int 除 Int 永遠(yuǎn)返回 Float
div(5, 2) # => 2 # 使用 div 截?cái)嘈?shù)點(diǎn)
5 \ 35 # => 7.0
2 ^ 2 # => 4 # 次方, 不是二進(jìn)制 xor
12 % 10 # => 2
# 用括號(hào)提高優(yōu)先級(jí)
(1 + 3) * 2 # => 8
# 二進(jìn)制操作符
~2 # => -3 # 非
3 & 5 # => 1 # 與
2 | 4 # => 6 # 或
2 $ 4 # => 6 # 異或
2 >>> 1 # => 1 # 邏輯右移
2 >> 1 # => 1 # 算術(shù)右移
2 << 1 # => 4 # 邏輯/算術(shù) 右移
# 可以用函數(shù) bits 查看二進(jìn)制數(shù)。
bits(12345)
# => "0000000000000000000000000000000000000000000000000011000000111001"
bits(12345.0)
# => "0100000011001000000111001000000000000000000000000000000000000000"
# 布爾值是原始類(lèi)型
true
false
# 布爾操作符
!true # => false
!false # => true
1 == 1 # => true
2 == 1 # => false
1 != 1 # => false
2 != 1 # => true
1 < 10 # => true
1 > 10 # => false
2 <= 2 # => true
2 >= 2 # => true
# 比較可以串聯(lián)
1 < 2 < 3 # => true
2 < 3 < 2 # => false
# 字符串可以由 " 創(chuàng)建
"This is a string."
# 字符字面量可用 ' 創(chuàng)建
'a'
# 可以像取數(shù)組取值一樣用 index 取出對(duì)應(yīng)字符
"This is a string"[1] # => 'T' # Julia 的 index 從 1 開(kāi)始 :(
# 但是對(duì) UTF-8 無(wú)效,
# 因此建議使用遍歷器 (map, for loops, 等).
# $ 可用于字符插值:
"2 + 2 = $(2 + 2)" # => "2 + 2 = 4"
# 可以將任何 Julia 表達(dá)式放入括號(hào)。
# 另一種格式化字符串的方式是 printf 宏.
@printf "%d is less than %f" 4.5 5.3 # 5 is less than 5.300000
# 打印字符串很容易
println("I'm Julia. Nice to meet you!")
####################################################
## 2\. 變量與集合
####################################################
# 給變量賦值就是聲明變量
some_var = 5 # => 5
some_var # => 5
# 訪問(wèn)未聲明變量會(huì)拋出異常
try
some_other_var # => ERROR: some_other_var not defined
catch e
println(e)
end
# 變量名需要以字母開(kāi)頭.
# 之后任何字母，數(shù)字，下劃線，嘆號(hào)都是合法的。
SomeOtherVar123! = 6 # => 6
# 甚至可以用 unicode 字符
? = 8 # => 8
# 用數(shù)學(xué)符號(hào)非常方便
2 * π # => 6.283185307179586
# 注意 Julia 的命名規(guī)約:
#
# * 變量名為小寫(xiě)，單詞之間以下劃線連接('\_')。
#
# * 類(lèi)型名以大寫(xiě)字母開(kāi)頭，單詞以 CamelCase 方式連接。
#
# * 函數(shù)與宏的名字小寫(xiě)，無(wú)下劃線。
#
# * 會(huì)改變輸入的函數(shù)名末位為 !。
# 這類(lèi)函數(shù)有時(shí)被稱(chēng)為 mutating functions 或 in-place functions.
# 數(shù)組存儲(chǔ)一列值，index 從 1 開(kāi)始。
a = Int64[] # => 0-element Int64 Array
# 一維數(shù)組可以以逗號(hào)分隔值的方式聲明。
b = [4, 5, 6] # => 包含 3 個(gè) Int64 類(lèi)型元素的數(shù)組: [4, 5, 6]
b[1] # => 4
b[end] # => 6
# 二維數(shù)組以分號(hào)分隔維度。
matrix = [1 2; 3 4] # => 2x2 Int64 數(shù)組: [1 2; 3 4]
# 使用 push! 和 append! 往數(shù)組末尾添加元素
push!(a,1) # => [1]
push!(a,2) # => [1,2]
push!(a,4) # => [1,2,4]
push!(a,3) # => [1,2,4,3]
append!(a,b) # => [1,2,4,3,4,5,6]
# 用 pop 彈出末尾元素
pop!(b) # => 6 and b is now [4,5]
# 可以再放回去
push!(b,6) # b 又變成了 [4,5,6].
a[1] # => 1 # 永遠(yuǎn)記住 Julia 的 index 從 1 開(kāi)始!
# 用 end 可以直接取到最后索引. 可用作任何索引表達(dá)式
a[end] # => 6
# 還支持 shift 和 unshift
shift!(a) # => 返回 1，而 a 現(xiàn)在時(shí) [2,4,3,4,5,6]
unshift!(a,7) # => [7,2,4,3,4,5,6]
# 以嘆號(hào)結(jié)尾的函數(shù)名表示它會(huì)改變參數(shù)的值
arr = [5,4,6] # => 包含三個(gè) Int64 元素的數(shù)組: [5,4,6]
sort(arr) # => [4,5,6]; arr 還是 [5,4,6]
sort!(arr) # => [4,5,6]; arr 現(xiàn)在是 [4,5,6]
# 越界會(huì)拋出 BoundsError 異常
try
a[0] # => ERROR: BoundsError() in getindex at array.jl:270
a[end+1] # => ERROR: BoundsError() in getindex at array.jl:270
catch e
println(e)
end
# 錯(cuò)誤會(huì)指出發(fā)生的行號(hào)，包括標(biāo)準(zhǔn)庫(kù)
# 如果你有 Julia 源代碼，你可以找到這些地方
# 可以用 range 初始化數(shù)組
a = [1:5] # => 5-element Int64 Array: [1,2,3,4,5]
# 可以切割數(shù)組
a[1:3] # => [1, 2, 3]
a[2:end] # => [2, 3, 4, 5]
# 用 splice! 切割原數(shù)組
arr = [3,4,5]
splice!(arr,2) # => 4 ; arr 變成了 [3,5]
# 用 append! 連接數(shù)組
b = [1,2,3]
append!(a,b) # a 變成了 [1, 2, 3, 4, 5, 1, 2, 3]
# 檢查元素是否在數(shù)組中
in(1, a) # => true
# 用 length 獲得數(shù)組長(zhǎng)度
length(a) # => 8
# Tuples 是 immutable 的
tup = (1, 2, 3) # => (1,2,3) # an (Int64,Int64,Int64) tuple.
tup[1] # => 1
try:
tup[1] = 3 # => ERROR: no method setindex!((Int64,Int64,Int64),Int64,Int64)
catch e
println(e)
end
# 大多數(shù)組的函數(shù)同樣支持 tuples
length(tup) # => 3
tup[1:2] # => (1,2)
in(2, tup) # => true
# 可以將 tuples 元素分別賦給變量
a, b, c = (1, 2, 3) # => (1,2,3) # a is now 1, b is now 2 and c is now 3
# 不用括號(hào)也可以
d, e, f = 4, 5, 6 # => (4,5,6)
# 單元素 tuple 不等于其元素值
(1,) == 1 # => false
(1) == 1 # => true
# 交換值
e, d = d, e # => (5,4) # d is now 5 and e is now 4
# 字典Dictionaries store mappings
empty_dict = Dict() # => Dict{Any,Any}()
# 也可以用字面量創(chuàng)建字典
filled_dict = ["one"=> 1, "two"=> 2, "three"=> 3]
# => Dict{ASCIIString,Int64}
# 用 [] 獲得鍵值
filled_dict["one"] # => 1
# 獲得所有鍵
keys(filled_dict)
# => KeyIterator{Dict{ASCIIString,Int64}}(["three"=>3,"one"=>1,"two"=>2])
# 注意，鍵的順序不是插入時(shí)的順序
# 獲得所有值
values(filled_dict)
# => ValueIterator{Dict{ASCIIString,Int64}}(["three"=>3,"one"=>1,"two"=>2])
# 注意，值的順序也一樣
# 用 in 檢查鍵值是否已存在，用 haskey 檢查鍵是否存在
in(("one", 1), filled_dict) # => true
in(("two", 3), filled_dict) # => false
haskey(filled_dict, "one") # => true
haskey(filled_dict, 1) # => false
# 獲取不存在的鍵的值會(huì)拋出異常
try
filled_dict["four"] # => ERROR: key not found: four in getindex at dict.jl:489
catch e
println(e)
end
# 使用 get 可以提供默認(rèn)值來(lái)避免異常
# get(dictionary,key,default_value)
get(filled_dict,"one",4) # => 1
get(filled_dict,"four",4) # => 4
# 用 Sets 表示無(wú)序不可重復(fù)的值的集合
empty_set = Set() # => Set{Any}()
# 初始化一個(gè) Set 并定義其值
filled_set = Set(1,2,2,3,4) # => Set{Int64}(1,2,3,4)
# 添加值
push!(filled_set,5) # => Set{Int64}(5,4,2,3,1)
# 檢查是否存在某值
in(2, filled_set) # => true
in(10, filled_set) # => false
# 交集，并集，差集
other_set = Set(3, 4, 5, 6) # => Set{Int64}(6,4,5,3)
intersect(filled_set, other_set) # => Set{Int64}(3,4,5)
union(filled_set, other_set) # => Set{Int64}(1,2,3,4,5,6)
setdiff(Set(1,2,3,4),Set(2,3,5)) # => Set{Int64}(1,4)
####################################################
## 3\. 控制流
####################################################
# 聲明一個(gè)變量
some_var = 5
# 這是一個(gè) if 語(yǔ)句，縮進(jìn)不是必要的
if some_var > 10
println("some_var is totally bigger than 10.")
elseif some_var < 10 # elseif 是可選的.
println("some_var is smaller than 10.")
else # else 也是可選的.
println("some_var is indeed 10.")
end
# => prints "some var is smaller than 10"
# For 循環(huán)遍歷
# Iterable 類(lèi)型包括 Range, Array, Set, Dict, 以及 String.
for animal=["dog", "cat", "mouse"]
println("$animal is a mammal")
# 可用 $ 將 variables 或 expression 轉(zhuǎn)換為字符串into strings
end
# prints:
# dog is a mammal
# cat is a mammal
# mouse is a mammal
# You can use 'in' instead of '='.
for animal in ["dog", "cat", "mouse"]
println("$animal is a mammal")
end
# prints:
# dog is a mammal
# cat is a mammal
# mouse is a mammal
for a in ["dog"=>"mammal","cat"=>"mammal","mouse"=>"mammal"]
println("$(a[1]) is a $(a[2])")
end
# prints:
# dog is a mammal
# cat is a mammal
# mouse is a mammal
for (k,v) in ["dog"=>"mammal","cat"=>"mammal","mouse"=>"mammal"]
println("$k is a $v")
end
# prints:
# dog is a mammal
# cat is a mammal
# mouse is a mammal
# While 循環(huán)
x = 0
while x < 4
println(x)
x += 1 # x = x + 1
end
# prints:
# 0
# 1
# 2
# 3
# 用 try/catch 處理異常
try
error("help")
catch e
println("caught it $e")
end
# => caught it ErrorException("help")
####################################################
## 4\. 函數(shù)
####################################################
# 用關(guān)鍵字 'function' 可創(chuàng)建一個(gè)新函數(shù)
#function name(arglist)
# body...
#end
function add(x, y)
println("x is $x and y is $y")
# 最后一行語(yǔ)句的值為返回
x + y
end
add(5, 6) # => 在 "x is 5 and y is 6" 后會(huì)打印 11
# 還可以定義接收可變長(zhǎng)參數(shù)的函數(shù)
function varargs(args...)
return args
# 關(guān)鍵字 return 可在函數(shù)內(nèi)部任何地方返回
end
# => varargs (generic function with 1 method)
varargs(1,2,3) # => (1,2,3)
# 省略號(hào) ... 被稱(chēng)為 splat.
# 剛剛用在了函數(shù)定義中
# 還可以用在函數(shù)的調(diào)用
# Array 或者 Tuple 的內(nèi)容會(huì)變成參數(shù)列表
Set([1,2,3]) # => Set{Array{Int64,1}}([1,2,3]) # 獲得一個(gè) Array 的 Set
Set([1,2,3]...) # => Set{Int64}(1,2,3) # 相當(dāng)于 Set(1,2,3)
x = (1,2,3) # => (1,2,3)
Set(x) # => Set{(Int64,Int64,Int64)}((1,2,3)) # 一個(gè) Tuple 的 Set
Set(x...) # => Set{Int64}(2,3,1)
# 可定義可選參數(shù)的函數(shù)
function defaults(a,b,x=5,y=6)
return "$a $b and $x $y"
end
defaults('h','g') # => "h g and 5 6"
defaults('h','g','j') # => "h g and j 6"
defaults('h','g','j','k') # => "h g and j k"
try
defaults('h') # => ERROR: no method defaults(Char,)
defaults() # => ERROR: no methods defaults()
catch e
println(e)
end
# 還可以定義鍵值對(duì)的參數(shù)
function keyword_args(;k1=4,name2="hello") # note the ;
return ["k1"=>k1,"name2"=>name2]
end
keyword_args(name2="ness") # => ["name2"=>"ness","k1"=>4]
keyword_args(k1="mine") # => ["k1"=>"mine","name2"=>"hello"]
keyword_args() # => ["name2"=>"hello","k1"=>4]
# 可以組合各種類(lèi)型的參數(shù)在同一個(gè)函數(shù)的參數(shù)列表中
function all_the_args(normal_arg, optional_positional_arg=2; keyword_arg="foo")
println("normal arg: $normal_arg")
println("optional arg: $optional_positional_arg")
println("keyword arg: $keyword_arg")
end
all_the_args(1, 3, keyword_arg=4)
# prints:
# normal arg: 1
# optional arg: 3
# keyword arg: 4
# Julia 有一等函數(shù)
function create_adder(x)
adder = function (y)
return x + y
end
return adder
end
# 這是用 "stabby lambda syntax" 創(chuàng)建的匿名函數(shù)
(x -> x > 2)(3) # => true
# 這個(gè)函數(shù)和上面的 create_adder 一模一樣
function create_adder(x)
y -> x + y
end
# 你也可以給內(nèi)部函數(shù)起個(gè)名字
function create_adder(x)
function adder(y)
x + y
end
adder
end
add_10 = create_adder(10)
add_10(3) # => 13
# 內(nèi)置的高階函數(shù)有
map(add_10, [1,2,3]) # => [11, 12, 13]
filter(x -> x > 5, [3, 4, 5, 6, 7]) # => [6, 7]
# 還可以使用 list comprehensions 替代 map
[add_10(i) for i=[1, 2, 3]] # => [11, 12, 13]
[add_10(i) for i in [1, 2, 3]] # => [11, 12, 13]
####################################################
## 5\. 類(lèi)型
####################################################
# Julia 有類(lèi)型系統(tǒng)
# 所有的值都有類(lèi)型；但變量本身沒(méi)有類(lèi)型
# 你可以用 `typeof` 函數(shù)獲得值的類(lèi)型
typeof(5) # => Int64
# 類(lèi)型是一等值
typeof(Int64) # => DataType
typeof(DataType) # => DataType
# DataType 是代表類(lèi)型的類(lèi)型，也代表他自己的類(lèi)型
# 類(lèi)型可用作文檔化，優(yōu)化，以及調(diào)度
# 并不是靜態(tài)檢查類(lèi)型
# 用戶還可以自定義類(lèi)型
# 跟其他語(yǔ)言的 records 或 structs 一樣
# 用 `type` 關(guān)鍵字定義新的類(lèi)型
# type Name
# field::OptionalType
# ...
# end
type Tiger
taillength::Float64
coatcolor # 不附帶類(lèi)型標(biāo)注的相當(dāng)于 `::Any`
end
# 構(gòu)造函數(shù)參數(shù)是類(lèi)型的屬性
tigger = Tiger(3.5,"orange") # => Tiger(3.5,"orange")
# 用新類(lèi)型作為構(gòu)造函數(shù)還會(huì)創(chuàng)建一個(gè)類(lèi)型
sherekhan = typeof(tigger)(5.6,"fire") # => Tiger(5.6,"fire")
# struct 類(lèi)似的類(lèi)型被稱(chēng)為具體類(lèi)型
# 他們可被實(shí)例化但不能有子類(lèi)型
# 另一種類(lèi)型是抽象類(lèi)型
# abstract Name
abstract Cat # just a name and point in the type hierarchy
# 抽象類(lèi)型不能被實(shí)例化，但是可以有子類(lèi)型
# 例如，Number 就是抽象類(lèi)型
subtypes(Number) # => 6-element Array{Any,1}:
# Complex{Float16}
# Complex{Float32}
# Complex{Float64}
# Complex{T<:Real}
# ImaginaryUnit
# Real
subtypes(Cat) # => 0-element Array{Any,1}
# 所有的類(lèi)型都有父類(lèi)型; 可以用函數(shù) `super` 得到父類(lèi)型.
typeof(5) # => Int64
super(Int64) # => Signed
super(Signed) # => Real
super(Real) # => Number
super(Number) # => Any
super(super(Signed)) # => Number
super(Any) # => Any
# 所有這些類(lèi)型，除了 Int64, 都是抽象類(lèi)型.
# <: 是類(lèi)型集成操作符
type Lion <: Cat # Lion 是 Cat 的子類(lèi)型
mane_color
roar::String
end
# 可以繼續(xù)為你的類(lèi)型定義構(gòu)造函數(shù)
# 只需要定義一個(gè)同名的函數(shù)
# 并調(diào)用已有的構(gòu)造函數(shù)設(shè)置一個(gè)固定參數(shù)
Lion(roar::String) = Lion("green",roar)
# 這是一個(gè)外部構(gòu)造函數(shù)，因?yàn)樗兕?lèi)型定義之外
type Panther <: Cat # Panther 也是 Cat 的子類(lèi)型
eye_color
Panther() = new("green")
# Panthers 只有這個(gè)構(gòu)造函數(shù)，沒(méi)有默認(rèn)構(gòu)造函數(shù)
end
# 使用內(nèi)置構(gòu)造函數(shù)，如 Panther，可以讓你控制
# 如何構(gòu)造類(lèi)型的值
# 應(yīng)該盡可能使用外部構(gòu)造函數(shù)而不是內(nèi)部構(gòu)造函數(shù)
####################################################
## 6\. 多分派
####################################################
# 在Julia中, 所有的具名函數(shù)都是類(lèi)屬函數(shù)
# 這意味著他們都是有很大小方法組成的
# 每個(gè) Lion 的構(gòu)造函數(shù)都是類(lèi)屬函數(shù) Lion 的方法
# 我們來(lái)看一個(gè)非構(gòu)造函數(shù)的例子
# Lion, Panther, Tiger 的 meow 定義為
function meow(animal::Lion)
animal.roar # 使用點(diǎn)符號(hào)訪問(wèn)屬性
end
function meow(animal::Panther)
"grrr"
end
function meow(animal::Tiger)
"rawwwr"
end
# 試試 meow 函數(shù)
meow(tigger) # => "rawwr"
meow(Lion("brown","ROAAR")) # => "ROAAR"
meow(Panther()) # => "grrr"
# 再看看層次結(jié)構(gòu)
issubtype(Tiger,Cat) # => false
issubtype(Lion,Cat) # => true
issubtype(Panther,Cat) # => true
# 定義一個(gè)接收 Cats 的函數(shù)
function pet_cat(cat::Cat)
println("The cat says $(meow(cat))")
end
pet_cat(Lion("42")) # => prints "The cat says 42"
try
pet_cat(tigger) # => ERROR: no method pet_cat(Tiger,)
catch e
println(e)
end
# 在面向?qū)ο笳Z(yǔ)言中，通常都是單分派
# 這意味著分派方法是通過(guò)第一個(gè)參數(shù)的類(lèi)型決定的
# 在Julia中, 所有參數(shù)類(lèi)型都會(huì)被考慮到
# 讓我們定義有多個(gè)參數(shù)的函數(shù)，好看看區(qū)別
function fight(t::Tiger,c::Cat)
println("The $(t.coatcolor) tiger wins!")
end
# => fight (generic function with 1 method)
fight(tigger,Panther()) # => prints The orange tiger wins!
fight(tigger,Lion("ROAR")) # => prints The orange tiger wins!
# 讓我們修改一下傳入具體為 Lion 類(lèi)型時(shí)的行為
fight(t::Tiger,l::Lion) = println("The $(l.mane_color)-maned lion wins!")
# => fight (generic function with 2 methods)
fight(tigger,Panther()) # => prints The orange tiger wins!
fight(tigger,Lion("ROAR")) # => prints The green-maned lion wins!
# 把 Tiger 去掉
fight(l::Lion,c::Cat) = println("The victorious cat says $(meow(c))")
# => fight (generic function with 3 methods)
fight(Lion("balooga!"),Panther()) # => prints The victorious cat says grrr
try
fight(Panther(),Lion("RAWR")) # => ERROR: no method fight(Panther,Lion)
catch
end
# 在試試讓 Cat 在前面
fight(c::Cat,l::Lion) = println("The cat beats the Lion")
# => Warning: New definition
# fight(Cat,Lion) at none:1
# is ambiguous with
# fight(Lion,Cat) at none:2.
# Make sure
# fight(Lion,Lion)
# is defined first.
#fight (generic function with 4 methods)
# 警告說(shuō)明了無(wú)法判斷使用哪個(gè) fight 方法
fight(Lion("RAR"),Lion("brown","rarrr")) # => prints The victorious cat says rarrr
# 結(jié)果在老版本 Julia 中可能會(huì)不一樣
fight(l::Lion,l2::Lion) = println("The lions come to a tie")
fight(Lion("RAR"),Lion("brown","rarrr")) # => prints The lions come to a tie
# Under the hood
# 你還可以看看 llvm 以及生成的匯編代碼
square_area(l) = l * l # square_area (generic function with 1 method)
square_area(5) #25
# 給 square_area 一個(gè)整形時(shí)發(fā)生什么
code_native(square_area, (Int32,))
# .section __TEXT,__text,regular,pure_instructions
# Filename: none
# Source line: 1 # Prologue
# push RBP
# mov RBP, RSP
# Source line: 1
# movsxd RAX, EDI # Fetch l from memory?
# imul RAX, RAX # Square l and store the result in RAX
# pop RBP # Restore old base pointer
# ret # Result will still be in RAX
code_native(square_area, (Float32,))
# .section __TEXT,__text,regular,pure_instructions
# Filename: none
# Source line: 1
# push RBP
# mov RBP, RSP
# Source line: 1
# vmulss XMM0, XMM0, XMM0 # Scalar single precision multiply (AVX)
# pop RBP
# ret
code_native(square_area, (Float64,))
# .section __TEXT,__text,regular,pure_instructions
# Filename: none
# Source line: 1
# push RBP
# mov RBP, RSP
# Source line: 1
# vmulsd XMM0, XMM0, XMM0 # Scalar double precision multiply (AVX)
# pop RBP
# ret
#
# 注意 只要參數(shù)中又浮點(diǎn)類(lèi)型，Julia 就使用浮點(diǎn)指令
# 讓我們計(jì)算一下圓的面積
circle_area(r) = pi * r * r # circle_area (generic function with 1 method)
circle_area(5) # 78.53981633974483
code_native(circle_area, (Int32,))
# .section __TEXT,__text,regular,pure_instructions
# Filename: none
# Source line: 1
# push RBP
# mov RBP, RSP
# Source line: 1
# vcvtsi2sd XMM0, XMM0, EDI # Load integer (r) from memory
# movabs RAX, 4593140240 # Load pi
# vmulsd XMM1, XMM0, QWORD PTR [RAX] # pi * r
# vmulsd XMM0, XMM0, XMM1 # (pi * r) * r
# pop RBP
# ret
#
code_native(circle_area, (Float64,))
# .section __TEXT,__text,regular,pure_instructions
# Filename: none
# Source line: 1
# push RBP
# mov RBP, RSP
# movabs RAX, 4593140496
# Source line: 1
# vmulsd XMM1, XMM0, QWORD PTR [RAX]
# vmulsd XMM0, XMM1, XMM0
# pop RBP
# ret
#以上內(nèi)容是否對(duì)您有幫助：
← json
更多建議：