Fortran的快速指南

“PQR”“一”“123'abc $％＃@！”

“一帖”“”

“PQR''A''123”ABC $％＃@！

'撇號'''

當上述代碼被編譯和執(zhí)行時，它產(chǎn)生了以下結(jié)果：

1
1
5
5
8
8

一個指針可以是：

• 未定義
• 關(guān)聯(lián)的
• 解除關(guān)聯(lián)

另外，在上述程序中，我們已關(guān)聯(lián)的指示器p1，與目標T1，使用=>運算符。相關(guān)的功能，測試指針的關(guān)聯(lián)狀態(tài)。

該廢止聲明的關(guān)聯(lián)從一個目標的指針。

抵消不清空目標，因為可能存在一個以上的指針指向同一目標。然而，排空指針意味著無效也。

例1

下面的示例演示的概念：

program pointerExample
implicit none
   integer, pointer :: p1
   integer, target :: t1 
   integer, target :: t2
   p1=>t1
   p1 = 1
   Print *, p1
   Print *, t1
   p1 = p1 + 4
   Print *, p1
   Print *, t1
   t1 = 8
   Print *, p1
   Print *, t1
   nullify(p1)
   Print *, t1
   p1=>t2
   Print *, associated(p1)
   Print*, associated(p1, t1)
   Print*, associated(p1, t2)
   !what is the value of p1 at present
   Print *, p1
   Print *, t2
   p1 = 10
   Print *, p1
   Print *, t2
end program pointerExample

當上述代碼被編譯和執(zhí)行時，它產(chǎn)生了以下結(jié)果：

1
1
5
5
8
8
8
T
F
T
952754640
952754640
10
10

請注意，每次運行代碼時，內(nèi)存地址會有所不同。

例2

program pointerExample
implicit none
   integer, pointer :: a, b
   integer, target :: t
   integer :: n
   t= 1
   a=>t
   t = 2
   b => t
   n = a + b
   Print *, a, b, t, n 
end program pointerExample

當上述代碼被編譯和執(zhí)行時，它產(chǎn)生了以下結(jié)果：

2  2  2  4

Fortran語言 - 基本輸入輸出

迄今為止，我們已經(jīng)看到，我們可以使用打印*語句讀取分別使用讀取*語句鍵盤和顯示輸出數(shù)據(jù)到屏幕上。輸入輸出的形式是自由格式的 I / O，它被稱為列表控制的輸入輸出。

自由格式簡單的I / O的形式為：

read(*,*) item1, item2, item3...
print *, item1, item2, item3
write(*,*) item1, item2, item3...

然而，格式化I / O讓您的數(shù)據(jù)傳輸更多的靈活性。

格式化輸入輸出

格式化輸入輸出有語法如下：

read fmt, variable_list 
print fmt, variable_list 
write fmt, variable_list 

哪里，

• FMT是格式規(guī)范

• 可變列表被從鍵盤被讀或?qū)懺谄聊簧系淖兞康牧斜?/p>

格式規(guī)范定義，其中顯示格式化的數(shù)據(jù)的方式。它由一個字符串，包含編輯描述符的括號中的列表。

一個編輯描述符指定的精確格式，例如，寬度，其中顯示后小數(shù)點等，數(shù)字字符和數(shù)字。

例如：

Print "(f6.3)", pi

下表描述了描述：

以下符號用于與格式描述符：

例1

program printPi
   pi = 3.141592653589793238 
   
   Print "(f6.3)", pi 
   Print "(f10.7)", pi
   Print "(f20.15)", pi 
   Print "(e16.4)", pi/100 
end program printPi

當上述代碼被編譯和執(zhí)行時，它產(chǎn)生了以下結(jié)果：

3.142
3.1415927
3.141592741012573
0.3142E-01

例2

program printName
implicit none
character (len=15) :: first_name
   print *,' Enter your first name.' 
   print *,' Up to 20 characters, please'
   read *,first_name 
   print "(1x,a)",first_name
end program printName

當上述代碼被編譯和執(zhí)行時，它產(chǎn)生了以下結(jié)果：（假設(shè)用戶輸入的名稱扎拉）

Enter your first name.
   Up to 20 characters, please
   Zara 

例3

program formattedPrint
implicit none
real :: c = 1.2786456e-9, d = 0.1234567e3 
integer :: n = 300789, k = 45, i = 2
character (len=15) :: str="Tutorials Point"
print "(i6)", k 
print "(i6.3)", k 
print "(3i10)", n, k, i 
print "(i10,i3,i5)", n, k, i 
print "(a15)",str 
print "(f12.3)", d
print "(e12.4)", c 
print '(/,3x,"n = ",i6, 3x, "d = ",f7.4)', n, d
end program formattedPrint

當上述代碼被編譯和執(zhí)行時，它產(chǎn)生了以下結(jié)果：

45
045
300789 45  2
300789 45  2
Tutorials Point
123.457
0.1279E-08

n = 300789 d = *******

該聲明的格式

格式語句允許您在一個聲明中混合和匹配字符，整數(shù)和實輸出。下面的例子說明了這一點：

program productDetails 
implicit none 
   character (len=15) :: name
   integer :: id 
   real :: weight
   name = 'Ardupilot'
   id = 1
   weight = 0.08
   print *,' The product details are' 
   print 100
   100 format (7x,'Name:', 7x, 'Id:', 1x, 'Weight:')
   print 200, name, id, weight 
   200 format(1x, a, 2x, i3, 2x, f5.2) 
end program productDetails

當上述代碼被編譯和執(zhí)行時，它產(chǎn)生了以下結(jié)果：

The product details are
Name:       Id:    Weight:
Ardupilot   1       0.08

Fortran語言 - 文件輸入輸出

Fortran語言，您可以讀取數(shù)據(jù)，并將數(shù)據(jù)寫入到文件中。

在最后一章，你看到了如何讀取數(shù)據(jù)，并將數(shù)據(jù)寫入到終端。在本章中，您將學習用Fortran語言提供的文件輸入和輸出功能。

可以讀取和寫入到一個或多個文件。開放，寫入，讀取和CLOSE語句，可以實現(xiàn)這一目標。

打開和關(guān)閉文件

使用文件之前，必須先打開該文件。 打開命令用來打開文件進行讀取或?qū)懭?。該命令的最簡單的形式是?

open (unit = number, file = "name").

然而，開放的聲明可能有一個一般形式：

open (list-of-specifiers)

下表介紹最常用的指示符：

該文件已被打開后，它是由讀寫語句訪問。一旦這樣做，就應(yīng)該使用CLOSE語句關(guān)閉。

close語句的語法如下：

close ([UNIT=]u[,IOSTAT=ios,ERR=err,STATUS=sta])

請注意，括號中的參數(shù)是可選的。

例

本實施例說明打開一個新文件的某些數(shù)據(jù)寫入到文件中。

program outputdata   
implicit none   
real, dimension(100) :: x, y  
real, dimension(100) :: p, q
integer :: i  
   ! data  
   do i=1,100  
   x(i) = i * 0.1 
   y(i) = sin(x(i)) * (1-cos(x(i)/3.0))  
   end do  
   ! output data into a file 
   open(1, file='data1.dat', status='new')  
   do i=1,100  
   write(1,*) x(i), y(i)   
   end do  
   close(1) 
end program outputdata

當上述代碼被編譯和執(zhí)行時，它創(chuàng)建的文件data1.dat和x和y數(shù)組值寫入到其中。然后關(guān)閉該文件。

讀取和寫入到文件

的讀寫語句分別用于讀和分別寫入到文件中。

他們的語法如下：

read ([UNIT=]u, [FMT=]fmt, IOSTAT=ios, ERR=err, END=s)
write([UNIT=]u, [FMT=]fmt, IOSTAT=ios, ERR=err, END=s)

大多數(shù)符的已在上表中進行討論。

結(jié)束= S說明是一個語句標號所在的程序跳轉(zhuǎn)，當它到達檔案結(jié)尾。

例

此示例演示讀取和寫入到文件中。

在這個項目中，我們從文件中讀取，我們在最后一個例子創(chuàng)建，data1.dat，并在屏幕上顯示。

program outputdata   
implicit none   
real, dimension(100) :: x, y  
real, dimension(100) :: p, q
integer :: i  
   ! data  
   do i=1,100  
   x(i) = i * 0.1 
   y(i) = sin(x(i)) * (1-cos(x(i)/3.0))  
   end do  
   ! output data into a file 
   open(1, file='data1.dat', status='new')  
   do i=1,100  
   write(1,*) x(i), y(i)   
   end do  
   close(1) 
  
   ! opening the file for reading
   open (2, file='data1.dat', status='old')
  
   do i=1,100  
   read(2,*) p(i), q(i)
   end do 
   close(2)
   do i=1,100  
   write(*,*) p(i), q(i)
   end do 
end program outputdata

當上述代碼被編譯和執(zhí)行時，它產(chǎn)生了以下結(jié)果：

0.100000001  5.54589933E-05
0.200000003  4.41325130E-04
0.300000012  1.47636665E-03
0.400000006  3.45637114E-03
0.500000000  6.64328877E-03
0.600000024  1.12552457E-02
0.699999988  1.74576249E-02
0.800000012  2.53552198E-02
0.900000036  3.49861123E-02
1.00000000   4.63171229E-02
1.10000002   5.92407547E-02
1.20000005   7.35742599E-02
1.30000007   8.90605897E-02
1.39999998   0.105371222    
1.50000000   0.122110792    
1.60000002   0.138823599    
1.70000005   0.155002072    
1.80000007   0.170096487    
1.89999998   0.183526158    
2.00000000   0.194692180    
2.10000014   0.202990443    
2.20000005   0.207826138    
2.29999995   0.208628103    
2.40000010   0.204863414    
2.50000000   0.196052119    
2.60000014   0.181780845    
2.70000005   0.161716297    
2.79999995   0.135617107    
2.90000010   0.103344671    
3.00000000   6.48725405E-02
3.10000014   2.02930309E-02
3.20000005  -3.01767997E-02
3.29999995  -8.61928314E-02
3.40000010  -0.147283033    
3.50000000  -0.212848678    
3.60000014  -0.282169819    
3.70000005  -0.354410470    
3.79999995  -0.428629100    
3.90000010  -0.503789663    
4.00000000  -0.578774154    
4.09999990  -0.652400017    
4.20000029  -0.723436713    
4.30000019  -0.790623367    
4.40000010  -0.852691114    
4.50000000  -0.908382416    
4.59999990  -0.956472993    
4.70000029  -0.995793998    
4.80000019  -1.02525222    
4.90000010  -1.04385209    
5.00000000  -1.05071592    
5.09999990  -1.04510069    
5.20000029  -1.02641726    
5.30000019  -0.994243503    
5.40000010  -0.948338211    
5.50000000  -0.888650239    
5.59999990  -0.815326691    
5.70000029  -0.728716135    
5.80000019  -0.629372001    
5.90000010  -0.518047631    
6.00000000  -0.395693362    
6.09999990  -0.263447165    
6.20000029  -0.122622721    
6.30000019   2.53026206E-02
6.40000010   0.178709000    
6.50000000   0.335851669    
6.59999990   0.494883657    
6.70000029   0.653881252    
6.80000019   0.810866773    
6.90000010   0.963840425    
7.00000000   1.11080539    
7.09999990   1.24979746    
7.20000029   1.37891412    
7.30000019   1.49633956    
7.40000010   1.60037732    
7.50000000   1.68947268    
7.59999990   1.76223695    
7.70000029   1.81747139    
7.80000019   1.85418403    
7.90000010   1.87160957    
8.00000000   1.86922085    
8.10000038   1.84674001    
8.19999981   1.80414569    
8.30000019   1.74167395    
8.40000057   1.65982044    
8.50000000   1.55933595    
8.60000038   1.44121361    
8.69999981   1.30668485    
8.80000019   1.15719533    
8.90000057   0.994394958    
9.00000000   0.820112705    
9.10000038   0.636327863    
9.19999981   0.445154816    
9.30000019   0.248800844    
9.40000057   4.95488606E-02
9.50000000  -0.150278628    
9.60000038  -0.348357052    
9.69999981  -0.542378068    
9.80000019  -0.730095863    
9.90000057  -0.909344316    
10.0000000  -1.07807255    

Fortran語言 - 程序

過程是一組執(zhí)行一個明確的任務(wù)，可以從你的程序中調(diào)用語句。信息（或數(shù)據(jù)）被傳遞給調(diào)用的程序，向步驟作為參數(shù)。

有兩種類型的程序：

• 功能
• 子程序

功能

函數(shù)是返回一個單一的量的過程。函數(shù)不應(yīng)該修改其參數(shù)。

返回的數(shù)量被稱為函數(shù)值 ，并且它由函數(shù)名表示。

句法：

語法功能如下：

function name(arg1, arg2, ....)  
   [declarations, including those for the arguments]   
   [executable statements] 
end function [name]

下面的示例演示一個名為功能area_of_circle。它計算半徑為r的圓的面積。

program calling_func
   real :: a
   a = area_of_circle(2.0) 
   Print *, "The area of a circle with radius 2.0 is"
   Print *, a
end program calling_func

function area_of_circle (r)  
! this function computes the area of a circle with radius r     
   implicit none      
! function result     
   real :: area_of_circle   
! dummy arguments     
   real :: r     
! local variables     
   real :: pi    
   pi = 4 * atan (1.0)     
   area_of_circle = pi * r**2  
end function area_of_circle

當你編譯和執(zhí)行上面的程序，它會產(chǎn)生以下結(jié)果：

The area of a circle with radius 2.0 is
   12.5663710   

請注意：

• 必須指定在兩個主程序隱無以及程序。

• 在被調(diào)用函數(shù)的參數(shù)r被稱為偽參數(shù) 。

結(jié)果選項

如果你想返回的值存儲在其它一些名稱與功能名稱，您可以使用結(jié)果選項。

您可以指定返回變量名：

function name(arg1, arg2, ....) result (return_var_name)  
   [declarations, including those for the arguments]   
   [executable statements] 
end function [name]

子程序

子程序沒有返回值，但可以修改其參數(shù)。

句法

subroutine name(arg1, arg2, ....)    
   [declarations, including those for the arguments]    
   [executable statements]  
end subroutine [name]

調(diào)用子程序

您需要使用呼叫語句調(diào)用的子程序。

下面的例子演示了一個子程序交換，改變其參數(shù)值的定義和使用。

program calling_func
implicit none
   real :: a, b
   a = 2.0
   b = 3.0
   Print *, "Before calling swap"
   Print *, "a = ", a
   Print *, "b = ", b
   call swap(a, b)
   Print *, "After calling swap"
   Print *, "a = ", a
   Print *, "b = ", b
end program calling_func

   subroutine swap(x, y) 
   implicit none
   real :: x, y, temp   
   temp = x  
   x = y 
   y = temp  
end subroutine swap

當你編譯和執(zhí)行上面的程序，它會產(chǎn)生以下結(jié)果：

Before calling swap
a = 2.00000000    
b = 3.00000000    
After calling swap
a = 3.00000000    
b = 2.00000000   

指定參數(shù)的意圖

這樣做的目的屬性允許你指定與參數(shù)在程序中使用的意圖。下表提供的意圖屬性的值：

下面的例子演示了這個概念：

program calling_func
implicit none
   real :: x, y, z, disc
   x= 1.0
   y = 5.0
   z = 2.0
   call intent_example(x, y, z, disc)
   Print *, "The value of the discriminant is"
   Print *, disc
end program calling_func

subroutine intent_example (a, b, c, d)     
   implicit none     
   ! dummy arguments      
   real, intent (in) :: a     
   real, intent (in) :: b      
   real, intent (in) :: c    
   real, intent (out) :: d   
   d = b*b - 4.0*a*c 
end subroutine intent_example

當你編譯和執(zhí)行上面的程序，它會產(chǎn)生以下結(jié)果：

The value of the discriminant is
   17.0000000    

遞歸過程

遞歸當編程語言，您可以調(diào)用同一個函數(shù)內(nèi)的函數(shù)發(fā)生。這就是所謂的函數(shù)的遞歸調(diào)用。

當一個過程調(diào)用本身，直接或間接地被稱為遞歸過程。你應(yīng)該通過其聲明之前遞歸字前面的聲明這種類型的程序。

當一個函數(shù)被遞歸使用， 結(jié)果選項被使用。

以下是一個例子，它計算階乘用于使用遞歸過程的給定數(shù)量：

program calling_func
implicit none
   integer :: i, f
   i = 15
   Print *, "The value of factorial 15 is"
   f = myfactorial(15)
   Print *, f
end program calling_func

recursive function myfactorial (n) result (fac)  
   ! computes the factorial of n (n!)      
   implicit none     
   ! function result     
   integer :: fac     
   ! dummy arguments     
   integer, intent (in) :: n     
   select case (n)         
   case (0:1)         
   fac = 1         
   case default    
   fac = n * myfactorial (n-1)  
   end select 
end function myfactorial

內(nèi)部程序

當一個過程被包含在程序中，它被稱為程序的內(nèi)部程序。包含的內(nèi)部程序的語法如下：

program program_name     
   implicit none         
   ! type declaration statements         
   ! executable statements    
   . . .     
   contains         
   ! internal procedures      
   . . .  
end program program_name

下面的例子演示了這個概念：

program mainprog  
implicit none 
real :: a, b 
   a = 2.0
   b = 3.0
   Print *, "Before calling swap"
   Print *, "a = ", a
   Print *, "b = ", b
   call swap(a, b)
   Print *, "After calling swap"
   Print *, "a = ", a
   Print *, "b = ", b
 
   contains   
   subroutine swap(x, y)     
   real :: x, y, temp      
   temp = x 
   x = y  
   y = temp   
   end subroutine swap 
end program mainprog   

當你編譯和執(zhí)行上面的程序，它會產(chǎn)生以下結(jié)果：

Before calling swap
a = 2.00000000    
b = 3.00000000    
After calling swap
a = 3.00000000    
b = 2.00000000   

Fortran語言 - 模塊

模塊就像一個包，你可以保持你的功能和子程序，如果你正在編寫一個非常大的項目，或者你的函數(shù)或子程序可以在多個程序中使用。

模塊為您提供多個文件之間的分裂你的程序的方式。

模塊用于：

• 包裝子程序，數(shù)據(jù)和接口塊。
• 限定，可以由一個以上的程序中使用的全局數(shù)據(jù)。
• 宣稱可以選擇的任何程序內(nèi)提供的變量。
• 導入模塊完全，使用，到另一個程序或子程序。

一個模塊的語法

一個模塊由兩部分組成：

• 規(guī)范一部分語句聲明
• 一個包含子程序和函數(shù)定義的一部分

模塊的一般形式是：

module name     
   [statement declarations]  
   [contains [subroutine and function definitions] ] 
end module [name]

使用一個模塊到你的程序

您可以將在通過使用語句程序或子程序模塊：

use name  

請注意

• 您可以添加盡可能多的模塊可以根據(jù)需要，將各自在不同的文件，并單獨編譯。

• 模塊可以以各種不同的程序中使用。

• 模塊可以在同一程序中可使用多次。

• 在模塊規(guī)范部分中聲明的變量是全局的模塊。

• 一個模塊中聲明的變量成為在使用的模塊的任何程序或常規(guī)全局變量。

• 使用聲明可以出現(xiàn)在主程序中，或它使用的程序或特定的模塊中定義的變量的任何其他子程序或模塊。

例

下面的例子演示了這個概念：

module constants  
implicit none 
   real, parameter :: pi = 3.1415926536  
   real, parameter :: e = 2.7182818285 
contains      
   subroutine show_consts()          
   print*, "Pi = ", pi          
   print*,  "e = ", e     
   end subroutine show_consts 
end module constants 

program module_example     
use constants      
implicit none     
   real :: x, ePowerx, area, radius 
   x = 2.0
   radius = 7.0
   ePowerx = e ** x
   area = pi * radius**2     
   call show_consts() 
   print*, "e raised to the power of 2.0 = ", ePowerx
   print*, "Area of a circle with radius 7.0 = ", area  
end program module_example

當你編譯和執(zhí)行上面的程序，它會產(chǎn)生以下結(jié)果：

Pi = 3.14159274    
e =  2.71828175    
e raised to the power of 2.0 = 7.38905573    
Area of a circle with radius 7.0 = 153.938049   

模塊中的變量和子程序的無障礙

缺省情況下，一個模塊中的所有的變量和子程序被提供給正在使用該模塊的代碼，通過使用語句的程序。

但是，你可以控制的模塊代碼使用私人和公共屬性的可訪問性。當你聲明一些變量或子程序為私有，這不是可用的模塊外。

例

下面的例子說明了這一概念：

在前面的例子中，我們有兩個模塊變量，e和圓周率。讓我們把他們的私人和觀察輸出：

module constants  
implicit none 
   real, parameter,private :: pi = 3.1415926536  
   real, parameter, private :: e = 2.7182818285 
contains      
   subroutine show_consts()          
   print*, "Pi = ", pi          
   print*, "e = ", e     
   end subroutine show_consts 
end module constants 

program module_example     
use constants      
implicit none     
   real :: x, ePowerx, area, radius 
   x = 2.0
   radius = 7.0
   ePowerx = e ** x
   area = pi * radius**2     
   call show_consts() 
   print*, "e raised to the power of 2.0 = ", ePowerx
   print*, "Area of a circle with radius 7.0 = ", area  
end program module_example

當你編譯和執(zhí)行上面的程序，它提供了以下錯誤信息：

   ePowerx = e ** x
   1
Error: Symbol 'e' at (1) has no IMPLICIT type
main.f95:19.13:

   area = pi * radius**2     
   1
Error: Symbol 'pi' at (1) has no IMPLICIT type

由于e和圓周率，既被聲明為私有，module_example無法再訪問這些變量程序。

然而，其他模塊的子程序可以訪問它們：

module constants  
implicit none 
   real, parameter,private :: pi = 3.1415926536  
   real, parameter, private :: e = 2.7182818285 
contains      
   subroutine show_consts()          
   print*, "Pi = ", pi          
   print*, "e = ", e     
   end subroutine show_consts 
   function ePowerx(x)result(ePx) 
   implicit none
   real::x
   real::ePx
   ePx = e ** x
   end function ePowerx
    
   function areaCircle(r)result(a)  
implicit none
   real::r
   real::a
   a = pi * r**2  
   end function areaCircle
    
end module constants 

program module_example     
use constants      
implicit none     
   call show_consts() 
   Print*, "e raised to the power of 2.0 = ", ePowerx(2.0)
   print*, "Area of a circle with radius 7.0 = ", areaCircle(7.0)  
end program module_example

當你編譯和執(zhí)行上面的程序，它會產(chǎn)生以下結(jié)果：

Pi = 3.14159274    
e = 2.71828175    
e raised to the power of 2.0 = 7.38905573    
Area of a circle with radius 7.0 = 153.938049   

Fortran語言 - 內(nèi)部函數(shù)

征函數(shù)是被提供作為Fortran語言的一部分的一些常見和重要的功能。我們的陣列，字符和字符串的章節(jié)已經(jīng)討論其中的一些功能。

本征函數(shù)可以被歸類為：

• 數(shù)值函數(shù)
• 數(shù)學函數(shù)
• 數(shù)字查詢函數(shù)
• 浮點操作函數(shù)
• 位操作功能
• 字符函數(shù)
• 種類函數(shù)
• 邏輯函數(shù)
• 陣列功能。

我們在陣列章節(jié)討論的陣列功能。在下面的部分，我們提供的其他類別所有這些功能的簡要說明。

在功能名稱列，

• A代表任何類型的數(shù)值變量
• R代表真實或整數(shù)變量
• X和Y代表實際變量
• Z表示復(fù)變
• W代表真實的或復(fù)雜的變量

數(shù)值函數(shù)

例

program numericFunctions
implicit none  
   ! define constants  
   !define variables
   real :: a, b 
   complex :: z
   !values for a, b 
   a = 15.2345
   b = -20.7689
    
   write(*,*) 'abs(a): ',abs(a),' abs(b): ',abs(b)   
   write(*,*) 'aint(a): ',aint(a),' aint(b): ',aint(b) 
   write(*,*) 'ceiling(a): ',ceiling(a),' ceiling(b): ',ceiling(b)   
   write(*,*) 'floor(a): ',floor(a),' floor(b): ',floor(b)  
    
   z = cmplx(a, b)
   write(*,*) 'z: ',z   
end program numericFunctions

當你編譯和執(zhí)行上面的程序，它會產(chǎn)生以下結(jié)果：

abs(a): 15.2344999   abs(b): 20.7688999    
aint(a): 15.0000000  aint(b): -20.0000000    
ceiling(a): 16  ceiling(b): -20
floor(a): 15  floor(b): -21
z: (15.2344999, -20.7688999)

數(shù)學函數(shù)

例

下面的程序一個時間后分別射彈的計算的水平和垂直位置x和y，叔：

其中，X = UT COS A和Y = UT罪 - 克T2 / 2

program projectileMotion  
implicit none  
   ! define constants  
   real, parameter :: g = 9.8  
   real, parameter :: pi = 3.1415927  
   !define variables
   real :: a, t, u, x, y   
   !values for a, t, and u 
   a = 45.0
   t = 20.0
   u = 10.0
   ! convert angle to radians  
   a = a * pi / 180.0  
   x = u * cos(a) * t   
   y = u * sin(a) * t - 0.5 * g * t * t  
   write(*,*) 'x: ',x,'  y: ',y   
end program projectileMotion

當你編譯和執(zhí)行上面的程序，它會產(chǎn)生以下結(jié)果：

x: 141.421356  y: -1818.57861  

數(shù)字查詢函數(shù)

這些功能與整數(shù)的某型號和浮點運算工作。該函數(shù)返回相同種類的變量X，它可以是真實的，在某些情況下整數(shù)的數(shù)的屬性。

浮點操作函數(shù)

位操作功能

字符函數(shù)

種類函數(shù)

邏輯功能

Fortran語言 - 數(shù)字精度

我們已經(jīng)討論了，在舊版本的Fortran，有兩個真正的類型：默認的實型和雙精度型。

然而，F(xiàn)ortran語言90/95提供了真實和整數(shù)數(shù)據(jù)類型通過一種 specifie精確的控制。

那種屬性

不同類型的數(shù)字是計算機內(nèi)部存儲方式不同。 那種屬性允許您指定一個數(shù)字在內(nèi)部存儲。例如，

real, kind = 2 :: a, b, c
real, kind = 4 :: e, f, g
integer, kind = 2 :: i, j, k
integer, kind = 3 :: l, m, n

在上述聲明中，實變量E，F(xiàn)和g具有比真實變量a，b和c更精確。整數(shù)變數(shù)l，m和n，可以存儲較大的值，并具有用于存儲比整數(shù)變量I，J和k多個數(shù)字。雖然這是依賴于機器。

例

program kindSpecifier
implicit none
   real(kind = 4) :: a, b, c
   real(kind = 8) :: e, f, g
   integer(kind = 2) :: i, j, k
   integer(kind = 4) :: l, m, n
   integer :: kind_a, kind_i, kind_e, kind_l
   kind_a = kind(a)
   kind_i = kind(i)
   kind_e = kind(e)
   kind_l = kind(l)
   print *,'default kind for real is', kind_a
   print *,'default kind for int is', kind_i
   print *,'extended kind for real is', kind_e
   print *,'default kind for int is', kind_l
end program kindSpecifier

當你編譯和執(zhí)行上面的程序它產(chǎn)生以下結(jié)果：

default kind for real is 4
default kind for int is 2
extended kind for real is 8
default kind for int is 4

查詢變量的大小

有許多內(nèi)在的功能，使您可以詢問數(shù)字的大小。

例如，BIT_SIZE（?。?/b>內(nèi)部函數(shù)指定用于存儲的位數(shù)。對于實數(shù)， 精度（x）的內(nèi)部函數(shù)，返回的精度小數(shù)位數(shù)，而范圍（x）的內(nèi)部函數(shù)返回指數(shù)的十進制范圍內(nèi)。

例

program getSize
implicit none
   real (kind = 4) :: a
   real (kind = 8) :: b
   integer (kind = 2) :: i
   integer (kind = 4) :: j

   print *,'precision of real(4) =', precision(a)
   print *,'precision of real(8) =', precision(b)
   
   print *,'range of real(4) =', range(a)
   print *,'range of real(8) =', range(b)
   

   print *,'maximum exponent of real(4) =' , maxexponent(a)
   print *,'maximum exponent of real(8) =' , maxexponent(b)
  
   print *,'minimum exponent of real(4) =' , minexponent(a)
   print *,'minimum exponent of real(8) =' , minexponent(b)
   
   print *,'bits in integer(2) =' , bit_size(i)
   print *,'bits in integer(4) =' , bit_size(j)
   
end program getSize

當你編譯和執(zhí)行上面的程序它產(chǎn)生以下結(jié)果：

precision of real(4) = 6
precision of real(8) = 15
range of real(4) = 37
range of real(8) = 307
maximum exponent of real(4) = 128
maximum exponent of real(8) = 1024
minimum exponent of real(4) = -125
minimum exponent of real(8) = -1021
bits in integer(2) = 16
bits in integer(4) = 32

獲取種類值

Fortran語言提供了兩個內(nèi)部函數(shù)來獲得一種價值整數(shù)和實數(shù)的精度要求：

• selected_int_kind（r）的
• selected_real_kind（[P，R]）

該selected_real_kind函數(shù)返回一個整數(shù)，是必要的一個給定的小數(shù)精度p和小數(shù)指數(shù)范圍r的那種類型的參數(shù)值。小數(shù)精度是顯著的位數(shù)，而小數(shù)指數(shù)范圍規(guī)定了最小和最大可表示數(shù)。因此，該范圍是從10-R 10 + R。

例如，selected_real_kind（P = 10，R = 99）返回需要10精確到小數(shù)點的那種價值，射程至少10-99到10 + 99。

例

program getKind
implicit none
   integer:: i
   i = selected_real_kind (p = 10, r = 99) 
   print *,'selected_real_kind (p = 10, r = 99)', i
end program getKind

當你編譯和執(zhí)行上面的程序它產(chǎn)生以下結(jié)果：

selected_real_kind (p = 10, r = 99) 8

Fortran語言 - 程序庫

有各種各樣的Fortran工具和庫。有些是免費的，有些是有償服務(wù)。

以下是一些免費的庫：

• RANDLIB，隨機數(shù)和統(tǒng)計分布發(fā)電機
• BLAS
• EISPACK
• GAMS-NIST指南可用數(shù)學軟件
• 從NIST一些統(tǒng)計數(shù)據(jù)和其他程序
• LAPACK
• LINPACK
• MINPACK
• 泥敷美容面膜
• NCAR數(shù)學庫
• 入Netlib集合的數(shù)學軟件，文件和數(shù)據(jù)庫。
• ODEPACK
• ODERPACK，一組例程的排名和排序。
• Expokit計算矩陣指數(shù)
• SLATEC
• SPECFUN
• STARPAC
• StatLib統(tǒng)計庫
• TOMS
• 排序和合并字符串

以下庫是不是免費的：

• 在NAG Fortran數(shù)值庫
• 在Visual Numerics的IMSL庫
• 數(shù)字食譜

Fortran語言 - 編程風格

編程風格是所有關(guān)于在開發(fā)項目如下一些規(guī)則。這些好的做法傳授像可讀性價值觀和明確性到您的程序。

一個好的程序應(yīng)該具有以下特點：

• 可讀性
• 正確的邏輯結(jié)構(gòu)
• 自注釋和評論

例如，如果你做類似下面的評論，它不會有很大幫助：

! loop from 1 to 10 
do i=1,10  

不過，如果你正在計算二項式系數(shù)，需要這個循環(huán)NCR的那么像這樣的評論會有所幫助：

! loop to calculate nCr 
do i=1,10

• 縮進代碼塊，使代碼明確各級。

• 自我檢查代碼，以確保零會有像師沒有數(shù)值誤差，負實數(shù)的負實數(shù)或?qū)?shù)的平方根。

• 包括確保變量不采取非法或超范圍值，即輸入驗證規(guī)范。

• 不把檢查哪里會是不必要的，減慢執(zhí)行。例如：

real :: x 
x = sin(y) + 1.0
if (x >= 0.0) then
z = sqrt(x)
end if

• 顯然，采用適當?shù)乃惴ň帉懙拇a。
• 使用拆分延續(xù)標記'和'長表達式。
• 做有意義的變量名。

Fortran語言 - 調(diào)試程序

調(diào)試器工具被用來搜索在程序中的錯誤。

調(diào)試器程序通過代碼幾步之遙，可以讓你的程序的執(zhí)行過程中檢查變量和其他數(shù)據(jù)對象的值。

它加載的源代碼，你都應(yīng)該運行調(diào)試器內(nèi)的程序。調(diào)試器調(diào)試程序是：

• 設(shè)置斷點，
• 通過源代碼步進，
• 設(shè)置觀察點。

斷點指定程序就停止了，代碼的臨界線后，專門。這些變量后，程序執(zhí)行在斷點處進行檢查。

調(diào)試程序也被檢查行源代碼行。

觀看點是在需要某些變量的值進行檢查，特別是后一個讀或?qū)懖僮鞯母鼽c。

gdb調(diào)試器

gdb調(diào)試器，GNU調(diào)試自帶的Linux操作系統(tǒng)。對于X窗口系統(tǒng)，GDB帶有一個圖形界面和程序被命名為xxgdb。

下表列出了GDB的一些命令：

dbx調(diào)試器

還有另外一個調(diào)試器，dbx調(diào)試器的Linux版本。

下表列出了dbx中的一些命令：

以上內(nèi)容是否對您有幫助：

在文檔使用的過程中是否遇到以下問題：

• 內(nèi)容錯誤
• 更新不及時
• 鏈接錯誤
• 缺少代碼/圖片示列
• 太簡單/步驟待完善
• 其他

更多建議：

提交建議

← 討論的Fortran

寫筆記

我要補充

精選筆記

Copyright©2021 w3cschool編程獅|閩ICP備15016281號-3|閩公網(wǎng)安備35020302033924號

違法和不良信息舉報電話：173-0602-2364|舉報郵箱：jubao@eeedong.com

在線筆記

App下載

掃描二維碼

下載編程獅App

公眾號

編程獅公眾號

意見反饋

意見反饋 X

• 意見反饋：

  聯(lián)系方式：

提交

查看完整版筆記 保存 關(guān)閉

教程糾錯 教程糾錯

違規(guī)舉報 X

• 廣告等垃圾信息
• 不友善內(nèi)容
• 違反法律法規(guī)的內(nèi)容
• 不宜公開討論的政治內(nèi)容
• 其他

提交

豆包